2 The User Interface of the AtlasRep Package

If tbl is the ordinary character table of an almost simple group G whose ordinary character table is contained in the ATLAS of Finite Groups then AtlasClassNames returns the list of class names for G, as defined above. The ordering of class names is the same as the ordering of the columns of tbl.

(The function may work also for almost simple non-ATLAS groups, but then clearly the class names returned are somewhat arbitrary.)

gap> AtlasClassNames( CharacterTable( "L3(4).3" ) );
[ "1A", "2A", "3A", "4ABC", "5A", "5B", "7A", "7B", "3B", "3B'", "3C", "3C'", 
  "6B", "6B'", "15A", "15A'", "15B", "15B'", "21A", "21A'", "21B", "21B'" ]
gap> AtlasClassNames( CharacterTable( "U3(5).2" ) );
[ "1A", "2A", "3A", "4A", "5A", "5B", "5CD", "6A", "7AB", "8AB", "10A", "2B", 
  "4B", "6D", "8C", "10B", "12B", "20A", "20B" ]
gap> AtlasClassNames( CharacterTable( "L2(27).6" ) );
[ "1A", "2A", "3AB", "7ABC", "13ABC", "13DEF", "14ABC", "2B", "4A", "26ABC", 
  "26DEF", "28ABC", "28DEF", "3C", "3C'", "6A", "6A'", "9AB", "9A'B'", "6B", 
  "6B'", "12A", "12A'" ]

2.5 Accessing Data of the AtlasRep Package

(Note that the output of the examples in this section refers to a perhaps outdated table of contents; the current version of the database may contain more information than is shown here.)

DisplayAtlasInfo lists the information available via the AtlasRep package, for the given inputs. Depending on the value of the remote component of the global variable AtlasOfGroupRepresentationsInfo (see AtlasOfGroupRepresentationsInfo), all the data provided by the ATLAS of Group Representations or only that in the local installation is available.

Called without arguments, DisplayAtlasInfo prints an overview what information the ATLAS of Group Representations provides. One line is printed for each group G, with the following columns.

group

the GAP name of G (see Group Names Used in the AtlasRep Package),

#

the number of representations stored for G,

maxes

the available straight line programsindexstraight line program for computing maximal subgroups of G,

cl

a + sign if at least one program for computing representatives of conjugacy classes of elements of G is stored, and a - sign otherwise,

cyc

a + sign if at least one program for computing representatives of classes of maximally cyclic subgroups of G is stored, and a - sign otherwise, and

out

descriptions of outer automorphisms of G for which at least one program is stored.

In the second form, listofnames must be a list of strings that are GAP names for a group from the ATLAS of Group Representations; in this case, the overview described above is restricted to the groups in this list.

In the third form, gapname must be a string that is a GAP name for a group from the ATLAS of Group Representations; in this case, DisplayAtlasInfo prints an overview of the information that is available for this group. One line is printed for each representation, showing the number of this representation (which is used in calls of AtlasGenerators, see AtlasGenerators), and a string of one of the following forms. G <= Sym(nid) denotes a permutation representation of degree n, and G <= GL(nid,descr) denotes a matrix representation of dimension n over a coefficient ring described by descr; in both cases, id is a (possible empty) string specifying the representation, for example G <= Sym(40a) and G <= Sym(40b) denote two (nonequivalent) representations of degree 40. In the case of matrix representations, descr can be a prime power, Z (denoting the ring of integers), a description of an algebraic extension field, C (denoting an unspecified algebraic extension field), or Z/mZ for an integer m (denoting the ring of residues mod m); for example, G <= GL(2a,4) and G <= GL(2b,4) denote two (nonequivalent) representations of dimension 2 over the field with four elements. After the representations, the straight line programs available for gapname are listed.

If the first argument is a string gapname, the following optional arguments can be used to restrict the overview.

std

must be a positive integer or a list of positive integers; if it is given then only those representations are considered that refer to the std-th set of standard generators or the i-th set of standard generators, for i in std (see Standard Generators Used in the AtlasRep Package),

IsPermGroup

restricts to permutation representations,

NrMovedPoints and n

for a positive integer or a list n, restrict to permutation representations of degree n or in the list n,

IsMatrixGroup

restricts to matrix representations,

Characteristic and p

for a prime integer or a list p, restrict to matrix representations over fields of characteristic p or in the list p (representations over residue class rings that are not fields can be addressed by p = fail),

Dimension and n

for a positive integer n or a list n, restrict to matrix representations of dimension n or in the list n, and

IsStraightLineProgram

restricts to straight line programs.

The representations are ordered as follows. Permutation representations come first (ordered according to the degree), followed by matrix representations over finite fields (ordered first according to the characteristic and second according to the dimension), matrix representations over the integers, and then matrix representations over algebraic extension fields (both kinds ordered according to the dimension), the last representations are matrix representations over residue class rings (ordered first according to the modulus and second according to the dimension).

Note that in each case, either the whole contents of the database or the contents of the local installation is considered, depending on whether the value of AtlasOfGroupRepresentationsInfo.remote is true or false (see AtlasOfGroupRepresentationsInfo).

gap> DisplayAtlasInfo( [ "M11", "A5" ] );
group     #  maxes  cl  cyc  out
--------------------------------
M11      42   1..5   +    +
A5       18   1..3   -    -

The above output means that the ATLAS of Group Representations contains 42 representations of the Mathieu group M₁₁, straight line programs for computing generators of representatives of all five classes of maximal subgroups, for computing representatives of the conjugacy classes of elements and of generators of maximally cyclic subgroups, and contains no straight line program for applying outer automorphisms (well, in fact M₁₁ admits no nontrivial outer automorphism). Analogously, 18 representations of the alternating group A₅ are available, straight line programs for computing generators of representatives of all three classes of maximal subgroups, and no straight line programs for computing representatives of the conjugacy classes of elements, of generators of maximally cyclic subgroups, and no for computing images under outer automorphisms.

gap> DisplayAtlasInfo( "A5", IsPermGroup );
Representations for G = A5:    (all refer to std. generators 1)
---------------------------
 1: G <= Sym(5)
 2: G <= Sym(6)
 3: G <= Sym(10)
gap> DisplayAtlasInfo( "A5", NrMovedPoints, [ 4 .. 9 ] );
Representations for G = A5:    (all refer to std. generators 1)
---------------------------
 1: G <= Sym(5)
 2: G <= Sym(6)

The first three representations stored for A₅ are (in fact primitive) permutation representations.

gap> DisplayAtlasInfo( "A5", Dimension, [ 1 .. 3 ] );
Representations for G = A5:    (all refer to std. generators 1)
---------------------------
 8: G <= GL(2a,4)
 9: G <= GL(2b,4)
10: G <= GL(3,5)
12: G <= GL(3a,9)
13: G <= GL(3b,9)
17: G <= GL(3a,Field([Sqrt(5)]))
18: G <= GL(3b,Field([Sqrt(5)]))
gap> DisplayAtlasInfo( "A5", Characteristic, 0 );
Representations for G = A5:    (all refer to std. generators 1)
---------------------------
14: G <= GL(4,Z)
15: G <= GL(5,Z)
16: G <= GL(6,Z)
17: G <= GL(3a,Field([Sqrt(5)]))
18: G <= GL(3b,Field([Sqrt(5)]))

The representations with number between 4 and 13 are (in fact irreducible) matrix representations over various finite fields, those with numbers 14 to 16 are integral matrix representations, and the last two are matrix representations over the field generated by Ö5 over the rational number field.

gap> DisplayAtlasInfo( "A5", IsStraightLineProgram );
Straight line programs for G = A5:    (all refer to std. generators 1)
----------------------------------
available maxes of G:  [ 1 .. 3 ]
class repres. of G available?  false
repres. of cyclic subgroups of G available?  false
available automorphisms:  [  ]
available other scripts:  [  ]

Straight line programs are available to compute generators of representatives of the three classes of maximal subgroups of A₅, see AtlasStraightLineProgram.

In the first two forms, gapname must be a string denoting a GAP name (see Group Names Used in the AtlasRep Package) of a group, and repnr a positive integer. If the ATLAS of Group Representations contains at least repnr representations for the group with GAP name gapname then AtlasGenerators, when called with gapname and repnr, returns an immutable record describing the repnr-th representation; otherwise fail is returned. If a third argument maxnr, a positive integer, is given then an immutable record describing the restriction of the repnr-th representation to the maxnr-th maximal subgroup is returned.

The result record has the following components.

generators

a list of generators for the group,

standardization

the positive integer denoting the underlying standard generators,

identifier

a GAP object (a list of filenames plus additional information) that uniquely determines the representation; the value can be used as identifier argument of AtlasGenerators (see below).

The third form of AtlasGenerators, with only argument identifier, can be used to fetch the result record with identifier value equal to identifier. The purpose of this variant is to access the same representation also in different GAP sessions.

gap> gens1:= AtlasGenerators( "A5", 1 );
rec( generators := [ (1,2)(3,4), (1,3,5) ], standardization := 1, 
  identifier := [ "A5", [ "A5G1-p5B0.m1", "A5G1-p5B0.m2" ], 1, 5 ] )
gap> gens8:= AtlasGenerators( "A5", 8 );
rec( 
  generators := [ [ [ Z(2)^0, 0*Z(2) ], [ Z(2^2), Z(2)^0 ] ], [ [ 0*Z(2), Z(2
                 )^0 ], [ Z(2)^0, Z(2)^0 ] ] ], standardization := 1, 
  identifier := [ "A5", [ "A5G1-f4r2aB0.m1", "A5G1-f4r2aB0.m2" ], 1, 4 ] )
gap> gens17:= AtlasGenerators( "A5", 17 );
rec( 
  generators := [ [ [ -1, 0, 0 ], [ 0, -1, 0 ], [ -E(5)-E(5)^4, -E(5)-E(5)^4, 
              1 ] ], [ [ 0, 1, 0 ], [ 0, 0, 1 ], [ 1, 0, 0 ] ] ], 
  standardization := 1, identifier := [ "A5", "A5G1-Ar3aB0.M", 1, 3 ] )

Each of the above pairs of elements generates a group isomorphic to A₅.

gap> gens1max2:= AtlasGenerators( "A5", 1, 2 );
rec( generators := [ (1,2)(3,4), (2,3)(4,5) ], standardization := 1, 
  identifier := [ "A5", [ "A5G1-p5B0.m1", "A5G1-p5B0.m2" ], 1, 5, 2 ] )
gap> id:= gens1max2.identifier;;
gap> gens1max2 = AtlasGenerators( id );
true
gap> max2:= Group( gens1max2.generators );;
gap> Size( max2 );
10
gap> IdGroup( max2 ) = IdGroup( DihedralGroup( 10 ) );
true

The elements stored in gens1max2.generators describe the restriction of the first representation of A₅ to a group in the second class of maximal subgroups of A₅ according to the list in the ATLAS of Finite Groups CCN85; this subgroup is isomorphic to the dihedral group D₁₀.

In all forms except the last one, gapname must be a string denoting a GAP name (see Group Names Used in the AtlasRep Package) of a group G, say, and std a positive integer denoting the standard generators of G used (see Standard Generators Used in the AtlasRep Package). If the ATLAS of Group Representations contains a straight line program (see Straight Line Programs in the GAP Reference Manual) as described by the other arguments (see below) then AtlasStraightLineProgram returns an immutable record with this program, otherwise fail is returned.

If the optional argument std is given, only those straight line programs are considered that take generators from the std-th set of standard generators of G as input.

The result record has the following components.

program

the required straight line program,

standardization

the positive integer denoting the underlying standard generators of G,

identifier

a GAP object (a list of filenames plus additional information) that uniquely determines the program; the value can be used as identifier argument of AtlasStraightLineProgram (see below).

In the first form, the last argument must be a positive integer maxnr, and the required program computes generators of the maxnr-th maximal subgroup of the group with GAP name gapname.

If the last argument is one of the strings "classes" or "cyclic" then the required program computes representatives of conjugacy classes of elements or representatives of generators of cyclic subgroups of G, respectively.

See BSW01 and SWW00 for the background concerning these straight line programs. In the second and third form of AtlasStraightLineProgram, the result record also contains a component outputs, whose value is a list of class names of the outputs, as described in Section Class Names Used in the AtlasRep Package.

If the last two arguments are "automorphism" and a string autname then the required program computes images of standard generators under the outer automorphism of G that is given by this string.

If the last two arguments are "other" and a string descr then the required program computes images of standard generators under the program that is described by this string. The last form of AtlasStraightLineProgram, with only argument identifier, can be used to fetch the result record with identifier value equal to identifier.

gap> prog:= AtlasStraightLineProgram( "A5", 2 );
rec( program := <straight line program>, standardization := 1, 
  identifier := [ "A5", "A5G1-max2W1", 1 ] )
gap> StringOfResultOfStraightLineProgram( prog.program, [ "a", "b" ] );
"[ a, bbab ]"
gap> gens1:= AtlasGenerators( "A5", 1 );
rec( generators := [ (1,2)(3,4), (1,3,5) ], standardization := 1, 
  identifier := [ "A5", [ "A5G1-p5B0.m1", "A5G1-p5B0.m2" ], 1, 5 ] )
gap> maxgens:= ResultOfStraightLineProgram( prog.program, gens1.generators );
[ (1,2)(3,4), (2,3)(4,5) ]
gap> maxgens = gens1max2.generators;
true

The above example shows that for restricting representations given by standard generators to a maximal subgroup of A₅, we can also fetch and apply the appropriate straight line program. Such a program (see Straight Line Programs in the GAP Reference Manual) takes standard generators of a group --in this example A₅-- as its input, and returns a list of elements in this group --in this example generators of the D₁₀ subgroup we had met above-- which are computed essentially by evaluating structured words in terms of the standard generators.

gap> prog:= AtlasStraightLineProgram( "J1", "cyclic" );
rec( program := <straight line program>, standardization := 1, 
  identifier := [ "J1", "J1G1-cycW1", 1 ],
  outputs := [ "6A", "7A", "10B", "11A", "15B", "19A" ] )
gap> gens:= GeneratorsOfGroup( FreeGroup( "x", "y" ) );;
gap> ResultOfStraightLineProgram( prog.program, gens );
[ x*y*x*y^2*x*y*x*y^2*x*y*x*y*x*y^2*x*y^2, x*y, x*y*x*y^2*x*y*x*y*x*y^2*x*y^2,
  x*y*x*y*x*y^2*x*y^2*x*y*x*y^2*x*y*x*y*x*y^2*x*y^2*x*y*x*y^2*x*y*x*y*x*y^
    2*x*y^2, x*y*x*y*x*y^2*x*y^2, x*y*x*y^2 ]

The above example shows how to fetch and use straight line programs for computing generators of representatives of maximally cyclic subgroups of a given group.

Let gapname be a string. If the ATLAS of Group Representations contains at least one representation for the group G with GAP name gapname and with the required properties then OneAtlasRepresentation returns an immutable record as described for AtlasGenerators (see AtlasGenerators) for such a representation; otherwise fail is returned. If the argument std is given then it must be a positive integer or a list of positive integers, denoting the sets of standard generators w.r.t. which the representation shall be given (see Standard Generators Used in the AtlasRep Package).

In the first form, OneAtlasGeneratingSet returns the first generating set for G, in the ordering shown by DisplayAtlasInfo (see DisplayAtlasInfo). In the remaining forms, IsPermGroup and IsMatrixGroup restrict to permutation and matrix representations, respectively, NrMovedPoints restricts to permutation representations of degree equal to the integer n or in the list n, Characteristic restricts to matrix representations of characteristic equal to the integer p or in the list p (representations over arbitrary residue class rings that are not fields can be accessed with p = fail), Dimension restricts to matrix representations of dimension equal to the positive integer m or in the list m, and Ring restricts to matrix representations for which all matrix entries are contained in the ring R.

Examples

First we access a permutation representation for the alternating group A₅.

gap> gens:= OneAtlasGeneratingSet( "A5" );
rec( generators := [ (1,2)(3,4), (1,3,5) ], standardization := 1, 
  identifier := [ "A5", [ "A5G1-p5B0.m1", "A5G1-p5B0.m2" ], 1, 5 ] )
gap> gens = OneAtlasGeneratingSet( "A5", IsPermGroup );
true
gap> gens = OneAtlasGeneratingSet( "A5", NrMovedPoints, [ 1 .. 10 ] );
true
gap> OneAtlasGeneratingSet( "A5", NrMovedPoints, 20 );
fail

Note that a permutation representation of degree 20 could be obtained by taking twice the primitive representation on 10 points; however, the ATLAS of Group Representations does not store this imprimitive representation (cf. Accessing vs. Constructing Representations).

Next we access matrix representations of A₅.

gap> gens:= OneAtlasGeneratingSet( "A5", IsMatrixGroup );
rec( 
  generators := [ <an immutable 4x4 matrix over GF2>, <an immutable 4x4 matrix\
 over GF2> ], standardization := 1, 
  identifier := [ "A5", [ "A5G1-f2r4aB0.m1", "A5G1-f2r4aB0.m2" ], 1, 2 ] )
gap> gens = OneAtlasGeneratingSet( "A5", Dimension, 4 );
true
gap> gens = OneAtlasGeneratingSet( "A5", Characteristic, 2 );
true
gap> OneAtlasGeneratingSet( "A5", Characteristic, [2,5], Dimension, 2 );
rec( 
  generators := [ [ [ Z(2)^0, 0*Z(2) ], [ Z(2^2), Z(2)^0 ] ], [ [ 0*Z(2), Z(2
                 )^0 ], [ Z(2)^0, Z(2)^0 ] ] ], standardization := 1, 
  identifier := [ "A5", [ "A5G1-f4r2aB0.m1", "A5G1-f4r2aB0.m2" ], 1, 4 ] )
gap> OneAtlasGeneratingSet( "A5", Characteristic, [2,5], Dimension, 1 );
fail
gap> gens:= OneAtlasGeneratingSet( "A5", Characteristic, 0, Dimension, 4 );
rec( 
  generators := [ [ [ 1, 0, 0, 0 ], [ 0, 0, 1, 0 ], [ 0, 1, 0, 0 ], [ -1, -1, 
              -1, -1 ] ], 
      [ [ 0, 1, 0, 0 ], [ 0, 0, 0, 1 ], [ 0, 0, 1, 0 ], [ 1, 0, 0, 0 ] ] ], 
  standardization := 1, identifier := [ "A5", "A5G1-Zr4B0.M", 1, 4 ] )
gap> gens = OneAtlasGeneratingSet( "A5", Ring, Integers );
true
gap> gens = OneAtlasGeneratingSet( "A5", Ring, CF(37) );
true
gap> OneAtlasGeneratingSet( "A5", Ring, Integers mod 77 );
fail
gap> gens:= OneAtlasGeneratingSet( "A5", Ring, CF(5), Dimension, 3 );
rec( 
  generators := [ [ [ -1, 0, 0 ], [ 0, -1, 0 ], [ -E(5)-E(5)^4, -E(5)-E(5)^4, 
              1 ] ], [ [ 0, 1, 0 ], [ 0, 0, 1 ], [ 1, 0, 0 ] ] ], 
  standardization := 1, identifier := [ "A5", "A5G1-Ar3aB0.M", 1, 3 ] )
gap> OneAtlasGeneratingSet( "A5", Ring, GF(17) );
fail

Note that a matrix representation in any characteristic can be obtained by reducing a permutation representation or an integral matrix representation; however, the ATLAS of Group Representations does not store such a representation (cf. Accessing vs. Constructing Representations).

2.6 Updating the Tables of Contents of the AtlasRep Package

The file atlasprm.g in the gap directory of the AtlasRep package contains the initial table of contents of the database. This file is read when the AtlasRep package is loaded. It may happen that new data files have been added to the servers since the last release of the AtlasRep package, thus it is useful to update the table of contents from time to time.

The data currently available on the servers or in the local data directories are inspected by ReloadAtlasTableOfContents, which updates the table of contents within a GAP session. After that, the new table of contents can be written to a local file with StoreAtlasTableOfContents. This file can then be read with ReplaceAtlasTableOfContents; it might be useful to put this command into the user's .gaprc file (see The .gaprc file in the GAP Reference Manual). Note that reading such a file is much more efficient than calling ReloadAtlasTableOfContents.

Users who have write access to the installation of the AtlasRep package can alternatively use the maketoc script in the etc directory of the package for regularly updating the file atlasprm.g.

Date and time of the last update of the table of contents are stored in its lastupdated component.

Let dirname be a string, which must be "local", "remote" or the name of a private data directory (see Chapter Private Extensions of the AtlasRep Package). ReloadAtlasTableOfContents replaces the table of contents of the AtlasRep package that is described by dirname by the one obtained from inspecting the actual contents of the data directories (see The Tables Of Contents of the Atlas of Group Representations).

Let filename be a string. StoreAtlasTableOfContents prints the loaded table of contents of the servers to the file with name filename.

Let filename be the name of a file that has been created with StoreAtlasTableOfContents (see StoreAtlasTableOfContents).

ReplaceAtlasTableOfContents first removes the information about the table of contents of the servers, and then reads the file with name filename, thus replacing the previous information by the stored one.

2.7 Examples of Using the AtlasRep Package

Example 1: Class Representatives

First we show the computation of class representatives of the Mathieu group M₁₁, in a 2-modular matrix representation. We start with the ordinary and Brauer character tables of this group.

gap> tbl:= CharacterTable( "M11" );;
gap> modtbl:= tbl mod 2;;
gap> CharacterDegrees( modtbl );
[ [ 1, 1 ], [ 10, 1 ], [ 16, 2 ], [ 44, 1 ] ]

The output of CharacterDegrees (see CharacterDegrees in the GAP Reference Manual) means that the 2-modular irreducibles of M₁₁ have degrees 1, 10, 16, 16, and 44.

Using DisplayAtlasInfo, we find out that matrix generators for the irreducible 10-dimensional representation; are available in the AtlasRep database.

gap> DisplayAtlasInfo( "M11", Characteristic, 2 );
Representations for G = M11:    (all refer to std. generators 1)
----------------------------
 6: G <= GL(10,2)
 7: G <= GL(32,2)
 8: G <= GL(44,2)
16: G <= GL(16b,4)
17: G <= GL(16a,4)

So we decide to work with this representation. We fetch the generators, and compute the list of class representatives of M₁₁ in the representation. The ordering of class representatives is the same as that in the character table of the ATLAS of Finite Groups (CCN85), which coincides with the ordering of columns in the GAP table we have fetched above.

gap> gens:= OneAtlasGeneratingSet( "M11", Characteristic, 2,
>                                         Dimension, 10 );;
gap> ccls:= AtlasStraightLineProgram( "M11", gens.standardization,
>                                     "classes" );
rec( program := <straight line program>, standardization := 1,
  identifier := [ "M11", "M11G1-cclsW1", 1 ],
  outputs := [ "1A", "2A", "3A", "4A", "5A", "6A", "8A", "8B", "11A", "11B" ]
 )
gap> reps:= ResultOfStraightLineProgram( ccls.program, gens.generators );;

Let us check whether the class representatives have the right orders.

gap> Length( reps );
10
gap> List( reps, Order ) = OrdersClassRepresentatives( tbl );
true

From the class representatives, we can compute the Brauer character we had started with. This Brauer character is defined on all classes of the 2-modular table. So we first pick only those representatives, using the GAP function GetFusionMap (see GetFusionMap in the GAP Reference Manual); in this situation, it returns the class fusion from the Brauer table into the ordinary table.

gap> fus:= GetFusionMap( modtbl, tbl );
[ 1, 3, 5, 9, 10 ]
gap> modreps:= reps{ fus };;

Then we call the GAP function BrauerCharacterValue (see BrauerCharacterValue in the GAP Reference Manual), which computes the Brauer character value from the matrix given.

gap> char:= List( modreps, BrauerCharacterValue );
[ 10, 1, 0, -1, -1 ]
gap> Position( Irr( modtbl ), char );
2

Example 2: Permutation and Matrix Representations

The second example shows the computation of a permutation representation from a matrix representation. We work with the 10-dimensional representation used above, and consider the action on the 2¹⁰ vectors of the underlying row space.

gap> grp:= Group( gens.generators );;
gap> v:= GF(2)^10;;
gap> orbs:= Orbits( grp, AsList( v ) );;
gap> List( orbs, Length );
[ 1, 396, 55, 330, 66, 165, 11 ]

We see that there are six nontrivial orbits, and we can compute the permutation actions on these orbits directly using Action. However, for larger examples, one cannot write down all orbits on the row space, so one has to use another strategy if one is interested in a particular orbit.

Let us assume that we are interested in the orbit of length 11. The point stabilizer is the first maximal subgroup of M₁₁, thus the restriction of the representation to this subgroup has a nontrivial fixed point space. This restriction can be computed using the AtlasRep package.

gap> gens:= AtlasGenerators( "M11", 6, 1 );;

Now computing the fixed point space is standard linear algebra.

gap> id:= IdentityMat( 10, GF(2) );;
gap> sub1:= Subspace( v, NullspaceMat( gens.generators[1] - id ) );;
gap> sub2:= Subspace( v, NullspaceMat( gens.generators[2] - id ) );;
gap> fix:= Intersection( sub1, sub2 );
<vector space of dimension 1 over GF(2)>

The final step is of course the computation of the permutation action on the orbit.

gap> orb:= Orbit( grp, Basis( fix )[1] );;
gap> act:= Action( grp, orb );;  Print( act, "\n" );
Group( [ ( 1, 2)( 4, 6)( 5, 8)( 7,10), ( 1, 3, 5, 9)( 2, 4, 7,11) ] )

Note that this group is not equal to the group obtained by fetching the permutation representation from the database. This is due to a different numbering of the points, so the groups are permutation isomorphic.

gap> permgrp:= Group( AtlasGenerators( "M11", 1 ).generators );;
gap> Print( permgrp, "\n" );
Group( [ ( 2,10)( 4,11)( 5, 7)( 8, 9), ( 1, 4, 3, 8)( 2, 5, 6, 9) ] )
gap> permgrp = act;
false
gap> IsConjugate( SymmetricGroup(11), permgrp, act );
true

Example 3: Outer Automorphisms

The straight line programs for applying outer automorphisms to standard generators can of course be used to define the automorphisms themselves as GAP mappings.

gap> DisplayAtlasInfo( "G2(3)", IsStraightLineProgram );
Straight line programs for G = G2(3):    (all refer to std. generators 1)
-------------------------------------
available maxes of G:  [ 1 .. 10 ]
class repres. of G available?  false
repres. of cyclic subgroups of G available?  true
available automorphisms:  [ "2" ]
available other scripts:  [  ]
gap> prog:= AtlasStraightLineProgram( "G2(3)", "automorphism", "2" ).program;;
gap> gens:= AtlasGenerators( "G2(3)", 1 ).generators;;
gap> imgs:= ResultOfStraightLineProgram( prog, gens );;
gap> g:= Group( gens );;

If we are not suspicious whether the script really describes an automorphism then we should tell this to GAP, in order to avoid the expensive checks of the properties of being a homomorphism and bijective (see Creating Group Homomorphisms in the GAP Reference Manual). This looks as follows.

gap> aut:= GroupHomomorphismByImagesNC( g, g, gens, imgs );;
gap> SetIsBijective( aut, true );

If we are suspicious whether the script describes an automorphism then we might have the idea to check it with GAP, as follows.

gap> aut:= GroupHomomorphismByImages( g, g, gens, imgs );;
gap> IsBijective( aut );
true

(However, even for a comparatively small group such as G₂(3), this is a difficult task, at least for GAP 4.2; in GAP 4.3, it will be easier.)

Often one can form images under an automorphism a, say, without creating the homomorphism object. This is obvious for the standard generators of the group G themselves, but also for generators of a maximal subgroup M computed from standard generators of G, provided that the straight line programs in question refer to the same standard generators. Note that the generators of M are given by evaluating words in terms of standard generators of G, and their images under a can be obtained by evaluating the same words at the images under a of the standard generators of G.

gap> max1:= AtlasStraightLineProgram( "G2(3)", 1 ).program;;
gap> mgens:= ResultOfStraightLineProgram( max1, gens );;
gap> comp:= CompositionOfStraightLinePrograms( max1, prog );;
gap> mimgs:= ResultOfStraightLineProgram( comp, gens );;

The list mgens is the list of generators of the first maximal subgroup of G₂(3), mimgs is the list of images under the automorphism given by the straight line program prog. Note that applying the program returned by CompositionOfStraightLinePrograms means to apply first prog and then max1. (From version 4.3 of GAP on, the function CompositionOfStraightLinePrograms is documented in the GAP Reference Manual.)

Since we have already constructed the GAP object representing the automorphism, we can check whether the results are equal.

gap> mimgs = List( mgens, x -> x^aut );
true

However, it should be emphasized that using aut requires a huge machinery of computations behind the scenes, whereas applying the straight line programs prog and max1 involves only elementary operations with the generators. The latter is feasible also for larger groups, for which constructing the GAP automorphism might be impossible.

Example 4: Using the GAP Library of Tables of Marks

The GAP library of tables of marks provides, for many almost simple groups, information for constructing representatives of all conjugacy classes of subgroups. If this information is compatible with the standard generators of the ATLAS of Group Representations then we can use it to restrict any representation from the ATLAS to prescribed subgroups. This is useful in particular for those subgroups for which the ATLAS of Group Representations itself does not contain a straight line program.

gap> tom:= TableOfMarks( "A5" );
TableOfMarks( "A5" )
gap> info:= StandardGeneratorsInfo( tom );
[ rec( generators := "a, b", description := "|a|=2, |b|=3, |ab|=5", 
      script := [ [ 1, 2 ], [ 2, 3 ], [ 1, 1, 2, 1, 5 ] ], ATLAS := true ) ]

The true value of the component ATLAS indicates that the information stored on tom refers to the standard generators of type 1 in the ATLAS of Group Representations.

We want to restrict a 4-dimensional integral representation of A₅ to a Sylow 2 subgroup of A₅, and use RepresentativeTomByGeneratorsNC (see RepresentativeTomByGeneratorsNC in the GAP Reference Manual) for that.

gap> stdgens:= OneAtlasGeneratingSet( "A5", Ring, Integers, Dimension, 4 );
rec( 
  generators := [ [ [ 1, 0, 0, 0 ], [ 0, 0, 1, 0 ], [ 0, 1, 0, 0 ], [ -1, -1, 
              -1, -1 ] ], 
      [ [ 0, 1, 0, 0 ], [ 0, 0, 0, 1 ], [ 0, 0, 1, 0 ], [ 1, 0, 0, 0 ] ] ], 
  standardization := 1, identifier := [ "A5", "A5G1-Zr4B0.M", 1, 4 ] )
gap> orders:= OrdersTom( tom );
[ 1, 2, 3, 4, 5, 6, 10, 12, 60 ]
gap> pos:= Position( orders, 4 );
4
gap> sub:= RepresentativeTomByGeneratorsNC( tom, pos, stdgens.generators );
<matrix group of size 4 with 2 generators>
gap> GeneratorsOfGroup( sub );
[ [ [ 1, 0, 0, 0 ], [ -1, -1, -1, -1 ], [ 0, 0, 0, 1 ], [ 0, 0, 1, 0 ] ], 
  [ [ 1, 0, 0, 0 ], [ 0, 0, 1, 0 ], [ 0, 1, 0, 0 ], [ -1, -1, -1, -1 ] ] ]

[Up] [Previous] [Next] [Index]