37 Groups

Group( gen, ... ) is the group generated by the arguments gen, ...

If the only argument gens is a list that is not a matrix then Group( gens ) is the group generated by the elements of that list.

If there are two arguments, a list gens and an element id, then Group( gens, id ) is the group generated by the elements of gens, with identity id.

Note that the value of the attribute GeneratorsOfGroup need not be equal to the list gens of generators entered as argument. Use GroupWithGenerators (see GroupWithGenerators) if you want to be sure that the argument gens is stored as value of GeneratorsOfGroup.

gap> g:=Group((1,2,3,4),(1,2));
Group([ (1,2,3,4), (1,2) ])

GroupWithGenerators returns the group G generated by the list gens. If a second argument id is present then this is stored as the identity element of the group. The value of the attribute GeneratorsOfGroup of G is equal to gens.

returns a list of generators of the group G. If G has been created by the command GroupWithGenerators (see GroupWithGenerators), with argument gens, then the list returned by GeneratorsOfGroup will be equal to gens.

gap> g:=GroupWithGenerators([(1,2,3,4),(1,2)]);
Group([ (1,2,3,4), (1,2) ])
gap> GeneratorsOfGroup(g);
[ (1,2,3,4), (1,2) ]

if the elements of the collection D form a group the command returns this group, otherwise it returns fail.

gap> AsGroup([(1,2)]);
fail
gap> AsGroup([(),(1,2)]);
Group([ (1,2) ])

returns the conjugate group of G, obtained by applying the conjugating element obj. To form a conjugate (group) by any object acting via ^, one can use the infix operator ^.

gap> ConjugateGroup(g,(1,5));
Group([ (2,3,4,5), (2,5) ])

A group is a magma-with-inverses (see IsMagmaWithInverses) and associative (see IsAssociative) multiplication.

IsGroup tests whether the object obj fulfills these conditions, it does not test whether obj is a set of elements that forms a group under multiplication; use AsGroup (see AsGroup) if you want to perform such a test. (See Categories for details about categories.)

gap> IsGroup(g);
true

is the info class for the generic group theoretic functions (see Info Functions).

37.3 Subgroups

For the general concept of parents and subdomains, see Parents and Constructing Subdomains. More functions that construct certain subgroups can be found in the sections Normal Structure, Specific and Parametrized Subgroups, Sylow Subgroups and Hall Subgroups, and Subgroups characterized by prime powers.

creates the subgroup U of G generated by gens. The Parent of U will be G. The NC version does not check, whether the elements in gens actually lie in G.

gap> u:=Subgroup(g,[(1,2,3),(1,2)]);
Group([ (1,2,3), (1,2) ])

For a subgroup U of the group G, Index returns the index [G :U ] = [(|G |)/(|G |)] of U in G. The NC version does not test whether U is contained in G.

gap> Index(g,u);
4

If the family of elements of G itself forms a group P, this attribute returns the index of G in P.

creates a subgroup of G which contains the same elements as U

gap> v:=AsSubgroup(g,Group((1,2,3),(1,4)));
Group([ (1,2,3), (1,4) ])
gap> Parent(v);
Group([ (1,2,3,4), (1,2) ])

IsSubgroup returns true if U is a group that is a subset of the domain G. This is actually checked by calling IsGroup( U ) and IsSubset( G, U ); note that special methods for IsSubset (see IsSubset) are available that test only generators of U if G is closed under the group operations. So in most cases, for example whenever one knows already that U is a group, it is better to call only IsSubset.

gap> IsSubgroup(g,u);
true
gap> v:=Group((1,2,3),(1,2));
Group([ (1,2,3), (1,2) ])
gap> u=v;
true
gap> IsSubgroup(g,v);
true

returns true if the group G normalizes the group U and false otherwise.

A group G normalizes a group U if and only if for every g Î G and u Î U the element u^g is a member of U. Note that U need not be a subgroup of G.

gap> IsNormal(g,u);
false

tests whether N is invariant under all automorphisms of G.

gap> IsCharacteristicSubgroup(g,u);
false

returns a list of all images of the group U under conjugation action by G.

A subgroup U of the group G is subnormal if it is contained in a subnormal series of G.

gap> IsSubnormal(g,Group((1,2,3)));
false
gap> IsSubnormal(g,Group((1,2)(3,4)));
true

If a group U is created as a subgroup of another group G, G becomes the parent of U. There is no universal parent group, parent-child chains can be arbitrary long. GAP stores the result of some operations (such as Normalizer) with the parent as an attribute.

37.4 Closures of (Sub)groups

creates the group generated by the elements of G and obj. obj can be either an element or a collection of elements, in particular another group.

gap> g:=SmallGroup(24,12);;u:=Subgroup(g,[g.3,g.4]);
Group([ f3, f4 ])
gap> ClosureGroup(u,g.2);
Group([ f2, f3, f4 ])
gap> ClosureGroup(u,[g.1,g.2]);
Group([ f1, f2, f3, f4 ])
gap> ClosureGroup(u,Group(g.2*g.1));
Group([ f1*f2^2, f3, f4 ])

These three functions together with ClosureGroupDefault implement the main methods for ClosureGroup (see ClosureGroup). In the ordering given, they just add elm to the generators, remove duplicates and identity elements, and test whether elm is already contained in G.

This functions returns the closure of the group G with the element elm. If G has the attribute AsSSortedList then also the result has this attribute. This is used to implement the default method for Enumerator (see Enumerator) and EnumeratorSorted (see EnumeratorSorted).

For a group G that stores a parent group (see Parents), ClosureSubgroup calls ClosureGroup (see ClosureGroup) with the same arguments; if the result is a subgroup of the parent of G then the parent of G is set as parent of the result, otherwise an error is raised. The check whether the result is contained in the parent of G is omitted by the NC version. As a wrong parent might imply wrong properties this version should be used with care.

37.5 Expressing Group Elements as Words in Generators

Using homomorphisms (see chapter Group Homomorphisms) is is possible to express group elements as words in given generators: Create a free group (see FreeGroup) on the correct number of generators and create a homomorphism from this free group onto the group G in whose generators you want to factorize. Then the preimage of an element of G is a word in the free generators, that will map on this element again. The following example shows how to decompose elements of S₄ in the generators (1,2,3,4) and (1,2):

gap> g:=Group((1,2,3,4),(1,2));
Group([ (1,2,3,4), (1,2) ])
gap> f:=FreeGroup("x","y");
<free group on the generators [ x, y ]>
gap> hom:=GroupHomomorphismByImagesNC(f,g,GeneratorsOfGroup(f),
> GeneratorsOfGroup(g));
[ x, y ] -> [ (1,2,3,4), (1,2) ]
gap> PreImagesRepresentative(hom,(1,4));
x*y^-1*x^-1

The following example stems from a real request to the GAP Forum. In September 2000 a GAP user working with puzzles wanted to express the permutation (15,16) as a word as short as possible in the generators of a particular permutation group of degree 16.

gap> perms := [ (1,2,3,7,11,10,9,5), (2,3,4,8,12,11,10,6),
>   (5,6,7,11,15,14,13,9), (6,7,8,12,16,15,14,10) ];;
gap> puzzle := Group( perms );;
gap> Size( puzzle );
20922789888000
gap> F := FreeGroup( "a", "b", "c", "d" );;
gap> gens := GeneratorsOfGroup( F );;
gap> hom := GroupHomomorphismByImages( F, puzzle, gens, perms );;
gap> word := PreImagesRepresentative( hom, (15,16) );;
gap> Length( word );
113

Because of the random methods involved in the function GroupHomomorphismByImages we may even get shorter words for the given permutation if we try it a few more times.

gap> words := [];;
gap> for i in [ 1 .. 10 ] do
>   hom := GroupHomomorphismByImages( F, puzzle, gens, perms );
>   word := PreImagesRepresentative( hom, (15,16) );
>   Add( words, word );
> od;
gap> List( words, word -> Length( word ) );
[ 33, 61, 53, 33, 33, 33, 49, 53, 75, 33 ]
gap> words[1];
c^-1*d^-1*c*b*d*b^-1*a^-1*b^-1*a^2*c*a^-1*d^-1*b*c^-1*b^-1*c*d*a^-1*b^
-1*a*d*a*c^-1*a^-1*b*d^-1*b^-1*d^-1*b*c^-1*b^-1*c

returns a factorization of elm as word in the generators of G given in the attribute GeneratorsOfGroup. (The corresponding free generators can be obtained via the family fam of the result as CollectionsFamily(fam)!.wholeGroup.)

The algorithm used computes all elements of the group to ensure a short word is found. Therefore this function should not be used when the group G has more than a few thousand elements. Because of this, one should not call this function within algorithms, but use homomorphisms instead.

gap> G:=SymmetricGroup( 6 );;
gap> r:=(3,4); s:=(1,2,3,4,5,6);
(3,4)
(1,2,3,4,5,6)
gap> # create a subgroup to force the system to use the generators r and s.
gap> H:= Subgroup(G, [ r, s ] );
Group([ (3,4), (1,2,3,4,5,6) ])
gap> Factorization( H, (1,2,3) );
x2*x1*x2*x1*x2^4
gap> s*r*s*r*s^4;
(1,2,3)

37.6 Cosets

returns the right coset of U with representative g, which is the set of all elements of the form ug for all u Î U . g must be an element of a larger group G which contains U. For element operations such as in a right coset behaves like a set of group elements.

Right cosets are external orbits for the action of U which acts via OnLeftInverse. Of course the action of a larger group G on right cosets is via OnRight.

gap> u:=Group((1,2,3), (1,2));;
gap> c:=RightCoset(u,(2,3,4));
RightCoset(Group( [ (1,2,3), (1,2) ] ),(2,3,4))
gap> ActingDomain(c);
Group([ (1,2,3), (1,2) ])
gap> Representative(c);
(2,3,4)
gap> Size(c);
6
gap> AsList(c);
[ (2,3,4), (1,4,2), (1,3)(2,4), (2,4), (1,4,2,3), (1,3,4,2) ]

computes a duplicate free list of right cosets Ug for g Î G . A set of representatives for the elements in this list forms a right transversal of U in G. (By inverting the representatives one obtains a list of representatives of the left cosets of U.) The NC version does not check whether U is a subgroup of G.

gap> RightCosets(g,u);
[ RightCoset(Group( [ (1,2,3), (1,2) ] ),()), 
  RightCoset(Group( [ (1,2,3), (1,2) ] ),(1,3)(2,4)), 
  RightCoset(Group( [ (1,2,3), (1,2) ] ),(1,4)(2,3)), 
  RightCoset(Group( [ (1,2,3), (1,2) ] ),(1,2)(3,4)) ]

returns a ``canonical'' representative of the coset Ug which is independent of the given representative g. This can be used to compare cosets by comparing their canonical representatives. The representative chosen to be the ``canonical'' one is representation dependent and only guaranteed to remain the same within one GAP session.

gap> CanonicalRightCosetElement(u,(2,4,3));
(3,4)

The category of right cosets.

GAP does not provide left cosets as a separate data type, but as the left coset gU consists of exactly the inverses of the elements of the right coset Ug^-1 calculations with left cosets can be emulated using right cosets by inverting the representatives.

37.7 Transversals

A right transversal t is a list of representatives for the set U \ G of right cosets (consisting of cosets Ug) of U in G.

The object returned by RightTransversal is not a plain list, but an object that behaves like an immutable list of length [G :U ], except if U is the trivial subgroup of G in which case RightTransversal may return the sorted plain list of coset representatives.

The operation PositionCanonical(t,g), called for a transversal t and an element g of G, will return the position of the representative in t that lies in the same coset of U as the element g does. (In comparison, Position will return fail if the element is not equal to the representative.) Functions that implement group actions such as Action or Permutation (see Chapter Group Actions) use PositionCanonical, therefore it is possible to ``act'' on a right transversal to implement the action on the cosets. This is often much more efficient than acting on cosets.

gap> g:=Group((1,2,3,4),(1,2));;
gap> u:=Subgroup(g,[(1,2,3),(1,2)]);;
gap> rt:=RightTransversal(g,u);
RightTransversal(Group([ (1,2,3,4), (1,2) ]),Group([ (1,2,3), (1,2) ]))
gap> Length(rt);
4
gap> Position(rt,(1,2,3));
fail

Note that the elements of a right transversal are not necessarily ``canonical'' in the sense of CanonicalRightCosetElement (see CanonicalRightCosetElement), but we may compute a list of canonical coset representatives by calling that function.

gap> List(RightTransversal(g,u),i->CanonicalRightCosetElement(u,i));
[ (), (2,3,4), (1,2,3,4), (3,4) ]

The operation PositionCanonical is described in section PositionCanonical.

gap> PositionCanonical(rt,(1,2,3));
1
gap> rt[1];
()

37.8 Double Cosets

The groups U and V must be subgroups of a common supergroup G of which g is an element. This command constructs the double coset UgV which is the set of all elements of the form ugv for any u Î U , v Î V . For element operations such as in, a double coset behaves like a set of group elements. The double coset stores U in the attribute LeftActingGroup, g as Representative, and V as RightActingGroup.

A double coset UgV can be considered as an union of right cosets U h_i. (it is the union of the orbit of Ug under right multiplication by V.) For a double coset D=UgV this returns a set of representatives h_i such that D =È_hiU h_i. The representatives returned are canonical for U (see CanonicalRightCosetElement) and form a set.

gap> u:=Subgroup(g,[(1,2,3),(1,2)]);;v:=Subgroup(g,[(3,4)]);;
gap> c:=DoubleCoset(u,(2,4),v);
DoubleCoset(Group( [ (1,2,3), (1,2) ] ),(2,4),Group( [ (3,4) ] ))
gap> (1,2,3) in c;
false
gap> (2,3,4) in c;
true
gap> LeftActingGroup(c);
Group([ (1,2,3), (1,2) ])
gap> RightActingGroup(c);
Group([ (3,4) ])
gap> RepresentativesContainedRightCosets(c);
[ (2,3,4) ]

computes a duplicate free list of all double cosets UgV for g Î G . U and V must be subgroups of the group G. The NC version does not check whether U and V are both subgroups of G.

gap> dc:=DoubleCosets(g,u,v);
[ DoubleCoset(Group( [ (1,2,3), (1,2) ] ),(),Group( [ (3,4) ] )), 
  DoubleCoset(Group( [ (1,2,3), (1,2) ] ),(1,3)(2,4),Group( [ (3,4) ] )), 
  DoubleCoset(Group( [ (1,2,3), (1,2) ] ),(1,4)(2,3),Group( [ (3,4) ] )) ]
gap> List(dc,Representative);
[ (), (1,3)(2,4), (1,4)(2,3) ]

The category of double cosets.

returns a list of double coset representatives and their sizes, the entries are lists of the form [rep ,size ]. This operation is faster that DoubleCosetsNC because no double coset objects have to be created.

gap> dc:=DoubleCosetRepsAndSizes(g,u,v);
[ [ (), 12 ], [ (1,3)(2,4), 6 ], [ (1,4)(2,3), 6 ] ]

The information function for coset and double coset operations is InfoCoset.

37.9 Conjugacy Classes

creates the conjugacy class in G with representative g. This class is an external set, so functions such as Representative (which returns g), ActingDomain (which returns G), StabilizerOfExternalSet (which returns the centralizer of g) and AsList work for it.

A conjugacy class is an external orbit (ExternalOrbit) of group elements with the group acting by conjugation on it. Thus element tests or operation representatives can be computed. The attribute Centralizer gives the centralizer of the representative (which is the same result as StabilizerOfExternalSet). (This is a slight abuse of notation: This is not the centralizer of the class as a set which would be the standard behaviour of Centralizer.)

returns the conjugacy classes of elements of G as a list of ConjugacyClasses of G (see ConjugacyClass (ConjugacyClass) for details). It is guaranteed that the class of the identity is in the first position, the further arrangement depends on the method chosen (and might be different for equal but not identical groups).

For very small groups (of size up to 500) the classes will be computed by the conjugation action of G on itself (see ConjugacyClassesByOrbits). This can be deliberately switched off using the ``noaction'' option shown below.

For solvable groups, the default method to compute the classes is by homomorphic lift (see section Conjugacy Classes in Solvable Groups).

For other groups the method of HulpkeClasses is employed.

ConjugacyClasses supports the following options that can be used to modify this strategy:

random

The classes are computed by random search. See ConjugacyClassesByRandomSearch (ConjugacyClassesByRandomSearch) below.

action

The classes are computed by action of G on itself See ConjugacyClassesByOrbits (ConjugacyClassesByOrbits) below.

noaction

Even for small groups ConjugacyClassesByOrbits (ConjugacyClassesByOrbits) is not used as a default. This can be useful if the elements of the group use a lot of memory.

gap> g:=SymmetricGroup(4);;
gap> cl:=ConjugacyClasses(g);
[ ()^G, (1,2)^G, (1,2)(3,4)^G, (1,2,3)^G, (1,2,3,4)^G ]
gap> Representative(cl[3]);Centralizer(cl[3]);
(1,2)(3,4)
Group([ (1,2), (1,3)(2,4), (3,4) ])
gap> Size(Centralizer(cl[5]));
4
gap> Size(cl[2]);
6

computes the classes of the group G by random search. This works very efficiently for almost simple groups.

This function is also accessible via the option random to ConjugacyClass.

computes the classes of the group G as orbits of G on its elements. This can be quick but unsurprisingly may also take a lot of memory if G becomes larger. All the classes will store their element list and thus a membership test will be quick as well.

This function is also accessible via the option action to ConjugacyClass.

gap> h:=Group((4,6)(5,7),(1,2,4)(3,6,5));;ConjugacyClasses(h:noaction);;time;
190
gap> h:=Group((4,6)(5,7),(1,2,4)(3,6,5));;ConjugacyClasses(h:random);;time;
130
gap> h:=Group((4,6)(5,7),(1,2,4)(3,6,5));;ConjugacyClasses(h:action);;time;
70

returns the number of conjugacy classes of G.

gap> g:=Group((1,2,3,4),(1,2));;
gap> NrConjugacyClasses(g);
5

creates the rational class in G with representative g. A rational class consists of all elements that are conjugate to g or to a power gⁱ where i is coprime to the order of g. Thus a rational class can be interpreted as a conjugacy class of cyclic subgroups. A rational class is an external set (IsExternalSet) of group elements with the group acting by conjugation on it, but not an external orbit.

returns a list of the rational classes of the group G. (See RationalClass.)

gap> RationalClasses(DerivedSubgroup(g));
[ RationalClass( AlternatingGroup( [ 1 .. 4 ] ), () ), 
  RationalClass( AlternatingGroup( [ 1 .. 4 ] ), (1,2)(3,4) ), 
  RationalClass( AlternatingGroup( [ 1 .. 4 ] ), (1,2,3) ) ]

Suppose that ratcl is a rational class of a group G with representative g. The exponents i for which g ⁱ lies already in the ordinary conjugacy class of g, form a subgroup of the prime residue class group P_n (see PrimitiveRootMod), the so-called Galois group of the rational class. The prime residue class group P_n is obtained in GAP as Units( Integers mod n ), the unit group of a residue class ring. The Galois group of a rational class rcl is stored in the attribute GaloisGroup(rcl) as a subgroup of this group.

tests whether the elements x and y or the subgroups U and V are conjugate under the action of G. (They do not need to be contained in G.) This command is only a shortcut to RepresentativeOperation.

gap> IsConjugate(g,Group((1,2,3,4),(1,3)),Group((1,3,2,4),(1,2)));
true

RepresentativeAction (see RepresentativeAction) can be used to obtain conjugating elements.

gap> RepresentativeAction(g,(1,2),(3,4));
(1,3)(2,4)

37.10 Normal Structure

For the operations Centralizer and Centre, see Chapter Magmas.

Computes the normalizer N_G(U), that is the stabilizer of U under the conjugation action of G. The second form computes N_G(ágñ).

gap> Normalizer(g,Subgroup(g,[(1,2,3)]));
Group([ (1,2,3), (2,3) ])

If S and U are groups of elements in the same family, this operation returns the core of U in S, that is the intersection of all S-conjugates of U.

gap> g:=Group((1,2,3,4),(1,2));;
gap> Core(g,Subgroup(g,[(1,2,3,4)]));
Group(())

The p-core of G is the largest normal p-subgroup of G. It is the core of a p-Sylow subgroup of G.

gap> PCore(g,2);
Group([ (1,4)(2,3), (1,3)(2,4) ])

The normal closure of U in G is the smallest normal subgroup of G which contains U.

gap> NormalClosure(g,Subgroup(g,[(1,2,3)]));
Group([ (1,2,3), (1,3,4) ])

computes the intersection of G and U, assuming that G is normalized by U. This works faster than Intersection, but will not produce the intersection if G is not normalized by U.

gap> NormalIntersection(Group((1,2)(3,4),(1,3)(2,4)),Group((1,2,3,4)));
Group([ (1,3)(2,4) ])

Let N be a normal subgroup of G. This command returns a set of representatives for the conjugacy classes of complements of N in G. Complements are subgroups U of G which intersect trivially with N and together with N generate G.

gap> Complementclasses(g,Group((1,2)(3,4),(1,3)(2,4)));
[ Group([ (3,4), (2,4,3) ]) ]

Info class for the complement routines.

37.11 Specific and Parametrized Subgroups

The Centre of a group (the subgroup of those elements that commute with all other elements of the group) can be computed by the operation Centre (see Centre).

gap> TrivialSubgroup(g);
Group(())

If G and H are two groups of elements in the same family, this operation returns the group generated by all commutators [ g, h ] = g^-1 h^-1 g h (see Comm) of elements g Î G and h Î H , that is the group á [ g, h ] | g Î G , h Î H ñ.

gap> CommutatorSubgroup(Group((1,2,3),(1,2)),Group((2,3,4),(3,4)));
Group([ (1,4)(2,3), (1,3,4) ])
gap> Size(last);
12

The derived subgroup G¢ of G is the subgroup generated by all commutators of pairs of elements of G. It is normal in G and the factor group G/G¢ is the largest abelian factor group of G.

gap> DerivedSubgroup(g);
Group([ (1,3,2), (1,4,3) ])

returns the minimal number n such that each element in the derived subgroup (see DerivedSubgroup) of the group G can be written as a product of (at most) n commutators of elements in G.

gap> CommutatorLength( g );
1

The Fitting subgroup of a group G is its largest nilpotent normal subgroup.

gap> FittingSubgroup(g);
Group([ (1,3)(2,4), (1,4)(2,3) ])

The Frattini subgroup of a group G is the intersection of all maximal subgroups of G.

gap> FrattiniSubgroup(g);
Group(())

returns a Prefrattini subgroup of the finite solvable group G. A factor M/N of G is called a Frattini factor if M/N £ f(G/N) holds. The group P is a Prefrattini subgroup of G if P covers each Frattini chief factor of G, and if for each maximal subgroup of G there exists a conjugate maximal subgroup, which contains P. In a finite solvable group G the Prefrattini subgroups form a characteristic conjugacy class of subgroups and the intersection of all these subgroups is the Frattini subgroup of G.

gap> G := SmallGroup( 60, 7 );
<pc group of size 60 with 4 generators>
gap> P := PrefrattiniSubgroup(G);
Group([ f2 ])
gap> Size(P);
2
gap> IsNilpotent(P);
true
gap> Core(G,P);
Group([  ])
gap> FrattiniSubgroup(G);
Group([  ])

is the smallest normal subgroup of G that has a solvable factor group.

gap> PerfectResiduum(Group((1,2,3,4,5),(1,2)));
Group([ (1,3,2), (1,4,3), (2,4,5) ])

is the radical of G, i.e., the largest solvable normal subgroup of G.

gap> RadicalGroup(SL(2,5));
<group of 2x2 matrices of size 2 in characteristic 5>
gap> Size(last);
2

The socle of the group G is the subgroup generated by all minimal normal subgroups.

gap> Socle(g);
Group([ (1,4)(2,3), (1,2)(3,4) ])

is the supersolvable residuum of the group G, that is, its smallest normal subgroup with supersolvable factor group.

gap> SupersolvableResiduum(g);
Group([ (1,2)(3,4), (1,4)(2,3) ])

The p-rump of a group G is the subgroup G¢G^p for a prime p.

@example missing!@

37.12 Sylow Subgroups and Hall Subgroups

returns a Sylow p subgroup of the finite group G. This is a p-subgroup of G whose index in G is coprime to p. SylowSubgroup computes Sylow subgroups via the operation SylowSubgroupOp.

gap> g:=SymmetricGroup(4);;
gap> SylowSubgroup(g,2);
Group([ (1,2), (3,4), (1,3)(2,4) ])

With respect to the following GAP functions, please note that by theorems of P. Hall, a group G is solvable if and only if one of the following conditions holds.

1. For each prime p dividing the order of G, there exists a p-complement (see SylowComplement).
2. For each set P of primes dividing the order of G, there exists a P-Hall subgroup (see HallSubgroup).
3. G has a Sylow system (see SylowSystem).
4. G has a complement system (see ComplementSystem).

returns a p-Sylow complement of the finite group G. This is a subgroup U of order coprime to p such that the index [G:U] is a p-power. At the moment methods exist only if G is solvable and GAP will issue an error if G is not solvable.

gap> SylowComplement(g,3);
Group([ (3,4), (1,4)(2,3), (1,3)(2,4) ])

computes a P-Hall subgroup for a set P of primes. This is a subgroup the order of which is only divisible by primes in P and whose index is coprime to all primes in P. The function computes Hall subgroups via the operation HallSubgroupOp. At the moment methods exist only if G is solvable and GAP will issue an error if G is not solvable.

gap> h:=SmallGroup(60,10);;
gap> u:=HallSubgroup(h,[2,3]);
Group([ f1, f2, f3 ])
gap> Size(u);
12

A Sylow system of a group G is a set of Sylow subgroups of G such that every pair of Sylow subgroups from this set commutes as subgroups. Sylow systems exist only for solvable groups. The operation returns fail if the group G is not solvable.

gap> h:=SmallGroup(60,10);;
gap> SylowSystem(h);
[ Group([ f1, f2 ]), Group([ f3 ]), Group([ f4 ]) ]
gap> List(last,Size);
[ 4, 3, 5 ]

A complement system of a group G is a set of Hall-p¢-subgroups of G, where p¢ runs through the subsets of prime factors of |G | that omit exactly one prime. Every pair of subgroups from this set commutes as subgroups. Complement systems exist only for solvable groups, therefore ComplementSystem returns fail if the group G is not solvable.

gap> ComplementSystem(h);
[ Group([ f3, f4 ]), Group([ f1, f2, f4 ]), Group([ f1, f2, f3 ]) ]
gap> List(last,Size);
[ 15, 20, 12 ]

returns a list containing one Hall-P subgroup for each set P of primes which occur in the order of G. Hall systems exist only for solvable groups. The operation returns fail if the group G is not solvable.

gap> HallSystem(h);
[ Group([  ]), Group([ f1, f2 ]), Group([ f1, f2, f3 ]), 
  Group([ f1, f2, f3, f4 ]), Group([ f1, f2, f4 ]), Group([ f3 ]), 
  Group([ f3, f4 ]), Group([ f4 ]) ]
gap> List(last,Size);
[ 1, 4, 12, 60, 20, 3, 15, 5 ]

37.13 Subgroups characterized by prime powers

For a p-group G, one defines W_n (G ) = { g Î G | g^{p n} = 1 }. The default value for n is 1.

@At the moment methods exist only for abelian G and n=1.@

gap> h:=SmallGroup(16,10);
<pc group of size 16 with 4 generators>
gap> Omega(h,2);
Group([ f4, f2, f3 ])

For a p-group G, one defines \mho_n (G) = ág^{p n} | g Î G ñ. The default value for n is 1.

gap> Agemo(h,2);Agemo(h,2,2);
Group([ f4 ])
Group([  ])

37.14 Group Properties

Some properties of groups can be defined not only for groups but also for other structures. For example, nilpotency and solvability make sense also for algebras. Note that these names refer to different definitions for groups and algebras, contrary to the situation with finiteness or commutativity. In such cases, the name of the function for groups got a suffix Group to distinguish different meanings for different structures.

A group is cyclic if it can be generated by one element. For a cyclic group, one can compute a generating set consisting of only one element using MinimalGeneratingSet (see MinimalGeneratingSet).

A group G is elementary abelian if it is commutative and if there is a prime p such that the order of each element in G divides p.

A group is nilpotent if the lower central series (see LowerCentralSeriesOfGroup for a definition) reaches the trivial subgroup in a finite number of steps.

The nilpotency class of a nilpotent group G is the number of steps in the lower central series of G (see LowerCentralSeriesOfGroup);

If G is not nilpotent an error is issued.

A group is perfect if it equals its derived subgroup (see DerivedSubgroup).

A group is solvable if the derived series (see DerivedSeriesOfGroup for a definition) reaches the trivial subgroup in a finite number of steps.

For finite groups this is the same as being polycyclic (see IsPolycyclicGroup), and each polycyclic group is solvable, but there are infinite solvable groups that are not polycyclic.

A group is polycyclic if it has a subnormal series with cyclic factors. For finite groups this is the same as if the group is solvable (see IsSolvableGroup).

A finite group is supersolvable if it has a normal series with cyclic factors.

A finite group is monomial if every irreducible complex character is induced from a linear character of a subgroup.

A group is simple if it has no nontrivial normal subgroups.

For a finite simple group G, IsomorphismTypeInfoFiniteSimpleGroup returns a record with components series, name and possibly parameter, describing the isomorphism type of G. The component name is a string that gives name(s) for G, and series is a string that describes the following series.

(If different characterizations of G are possible only one is given by series and parameter, while name may give several names.)

"A"

Alternating groups, parameter gives the natural degree.

"L"

Linear groups (Chevalley type A), parameter is a list [n,q] that indicates L(n,q).

"2A"

Twisted Chevalley type ²A, parameter is a list [n,q] that indicates ²A(n,q).

"B"

Chevalley type B, parameter is a list [n,q] that indicates B(n,q).

"2B"

Twisted Chevalley type ²B, parameter is a value q that indicates ²B(2,q).

"C"

Chevalley type C, parameter is a list [n,q] that indicates C(n,q).

"D"

Chevalley type D, parameter is a list [n,q] that indicates D(n,q).

"2D"

Twisted Chevalley type ²D, parameter is a list [n,q] that indicates ²D(n,q).

"3D"

Twisted Chevalley type ³D, parameter is a value q that indicates ³D(4,q).

"E"

Exceptional Chevalley type E, parameter is a list [n,q] that indicates E_n(q). The value of n is 6,7 or 8.

"2E"

Twisted exceptional Chevalley type E₆, parameter is a value q that indicates ²E₆(q).

"F"

Exceptional Chevalley type F, parameter is a value q that indicates F(4,q).

"2F"

Twisted exceptional Chevalley type ²F (Ree groups), parameter is a value q that indicates ²F(4,q).

"G"

Exceptional Chevalley type G, parameter is a value q that indicates G(2,q).

"2G"

Twisted exceptional Chevalley type ²G (Ree groups), parameter is a value q that indicates ²G(2,q).

"Spor"

Sporadic groups, name gives the name.

"Z"

Cyclic groups of prime size, parameter gives the size.

An equal sign in the name denotes different naming schemes for the same group, a tilde sign abstract isomorphisms between groups constructed in a different way.

gap> IsomorphismTypeInfoFiniteSimpleGroup(Group((4,5)(6,7),(1,2,4)(3,5,6)));
rec( series := "L", parameter := [ 2, 7 ], 
  name := "A(1,7) = L(2,7) ~ B(1,7) = O(3,7) ~ C(1,7) = S(2,7) ~ 2A(1,7) = U(2\
,7) ~ A(2,2) = L(3,2)" )

tests whether the group G can be generated by a finite number of generators. (This property is mainly used to obtain finiteness conditions.)

A group is called locally finite if every finitely generated subgroup is finite. This property checks whether the group U is a subset of a locally finite group. This is used to check whether finite generation will imply finiteness, as it does for example for permutation groups.

A p-group is a finite group whose order (see Size) is of the form pⁿ for a prime integer p and a nonnegative integer n. IsPGroup returns true if G is a p-group, and false otherwise.

If G is a nontrivial p-group (see IsPGroup), PrimePGroup returns the prime integer p; if G is trivial then PrimePGroup returns fail. Otherwise an error is issued.

The p-class of a p-group G (see IsPGroup) is the length of the lower p-central series (see PCentralSeries) of G. If G is not a p-group then an error is issued.

For a p-group G (see IsPGroup), RankPGroup returns the rank of G, which is defined as the minimal size of a generating system of G. If G is not a p-group then an error is issued.

gap> h:=Group((1,2,3,4),(1,3));;
gap> PClassPGroup(h);
2
gap> RankPGroup(h);
2

Note that the following functions, although they are mathematical properties, are not properties in the sense of GAP (see Attributes and Properties), as they depend on a parameter.

A group is p-solvable if every chief factor is either not divisible by p or solvable.

@Currently no method is installed!@

A group is p-nilpotent if it possesses a normal p-complement.

37.15 Numerical Group Attributes

returns the abelian invariants of the commutator factor group of the group G. They are given as a list of the orders of a set of independent generators of G/G¢ (see IndependentGeneratorsOfAbelianGroup).

gap> g:=Group((1,2,3,4),(1,2),(5,6));;
gap> AbelianInvariants(g);
[ 2, 2 ]

The exponent e of a group G is the lcm of the orders of its elements, that is, e is the smallest integer such that g^e=1 for all g Î G

gap> Exponent(g);
12

Again the following are mathematical attributes, but not GAP Attributes as they are depending on a parameter:

returns the number of n-tuples (g₁, g₂, ¼g_n) of elements of the group G that generate the whole group G. The elements of an n-tuple need not be different.

gap> EulerianFunction(g,2);
432

37.16 Subgroup Series

In group theory many subgroup series are considered, and GAP provides commands to compute them. In the following sections, there is always a series G = U₁ > U₂ > ¼ > U_m = á1 ñ of subgroups considered. A series also may stop without reaching G or á1ñ.

A series is called subnormal if every U_i+1 is normal in U_i.

A series is called normal if every U_i is normal in G.

A series of normal subgroups is called central if U_i/U_i+1 is central in G/U_i+1.

We call a series refinable if intermediate subgroups can be added to the series without destroying the properties of the series.

Unless explicitly declared otherwise, all subgroup series are descending. That is they are stored in decreasing order.

is a series of normal subgroups of G which cannot be refined further. That is there is no normal subgroup N of G with U_i > N > U_i+1. This attribute returns one chief series (of potentially many possibilities).

gap> g:=Group((1,2,3,4),(1,2));;
gap> ChiefSeries(g);
[ Group([ (1,2,3,4), (1,2) ]), Group([ (2,4,3), (1,4)(2,3), (1,3)(2,4) ]), 
  Group([ (1,4)(2,3), (1,3)(2,4) ]), Group(()) ]

is a chief series of the group G going through the normal subgroups in the list l. l must be a list of normal subgroups of G contained in each other, sorted by descending size. This attribute returns one chief series (of potentially many possibilities).

returns a series of normal subgroups of G which are invariant under H such that the series cannot be refined any further. G must be a subgroup of H. This attribute returns one such series (of potentially many possibilities).

If U is a subgroup of G this operation returns a subnormal series that descends from G to a subnormal subgroup V ³ U. If U is subnormal, V=U.

gap> s:=SubnormalSeries(g,Group((1,2)(3,4)));
[ Group([ (1,2,3,4), (1,2) ]), Group([ (1,2)(3,4), (1,3)(2,4) ]), 
  Group([ (1,2)(3,4) ]) ]

A composition series is a subnormal series which cannot be refined. This attribute returns one composition series (of potentially many possibilities).

Displays a composition series of G in a nice way, identifying the simple factors.

gap> CompositionSeries(g);
[ Group([ (3,4), (2,4,3), (1,4)(2,3), (1,3)(2,4) ]), 
  Group([ (2,4,3), (1,4)(2,3), (1,3)(2,4) ]), 
  Group([ (1,4)(2,3), (1,3)(2,4) ]), Group([ (1,3)(2,4) ]), Group(()) ]
gap> DisplayCompositionSeries(Group((1,2,3,4,5,6,7),(1,2)));
G (6 gens, size 5040)
 | Z(2)
S (5 gens, size 2520)
 | A(7)
1 (0 gens, size 1)

The derived series of a group is obtained by U_i+1=U_i¢. It stops if U_i is perfect.

The derived length of a group is the number of steps in the derived series. (As there is always the group, it is the series length minus 1.)

gap> List(DerivedSeriesOfGroup(g),Size);
[ 24, 12, 4, 1 ]
gap> DerivedLength(g);
3

returns a series of normal subgroups of G such that all factors are elementary abelian. If the group is not solvable (and thus no such series exists) it returns fail.

The variant ElementaryAbelianSeriesLargeSteps tries to make the steps in this series large (by eliminating intermediate subgroups if possible) at a small additional cost.

In the third variant, an elementary abelian series through the given series of normal subgroups is constructed.

gap> List(ElementaryAbelianSeries(g),Size);
[ 24, 12, 4, 1 ]

For a (solvable) group G and a list of automorphisms morph of G, this command finds a normal series of G with elementary abelian factors such that every group in this series is invariant under every automorphism in morph.

If a normal subgroup N of G which is invariant under morph is given, this series is chosen to contain N. No tests are performed to check the validity of the arguments.

The series obtained will be constructed to prefer large steps unless fine is given as true.

gap> g:=Group((1,2,3,4),(1,3));
Group([ (1,2,3,4), (1,3) ])
gap> hom:=GroupHomomorphismByImages(g,g,GeneratorsOfGroup(g),
> [(1,4,3,2),(1,4)(2,3)]);
[ (1,2,3,4), (1,3) ] -> [ (1,4,3,2), (1,4)(2,3) ]
gap> InvariantElementaryAbelianSeries(g,[hom]);
[ Group([ (1,2,3,4), (1,3) ]), Group([ (1,3)(2,4) ]), Group(()) ]

The lower central series of a group G is defined as U_i+1:=[G,U_i]. It is a central series of normal subgroups. The name derives from the fact that U_i is contained in the i-th step subgroup of any central series.

The upper central series of a group G is defined as an ending series U_i/U_i+1:=Z(G/U_i+1). It is a central series of normal subgroups. The name derives from the fact that U_i contains every i-th step subgroup of a central series.

The p-central series of G is defined by U₁:=G, U_i:=[G,U_i-1]U_i-1^p.

For a p-group G, this function returns its Jennings series. This series is defined by setting G₁=G and for i ³ 0, G_i+1=[G_i,G]G_j^p, where j is the smallest integer ³ i/p.

This operation computes the dimensions of the factors of the Loewy series of G. (See Hup82, p. 157 for the slightly complicated definition of the Loewy Series.)

The dimensions are computed via the JenningsSeries without computing the Loewy series itself.

gap> G:= SmallGroup( 3^6, 100 );
<pc group of size 729 with 6 generators>
gap> JenningsSeries( G );
[ <pc group of size 729 with 6 generators>, Group([ f3, f4, f5, f6 ]), 
  Group([ f4, f5, f6 ]), Group([ f5, f6 ]), Group([ f5, f6 ]), 
  Group([ f5, f6 ]), Group([ f6 ]), Group([ f6 ]), Group([ f6 ]), 
  Group([ <identity> of ... ]) ]
gap> DimensionsLoewyFactors(G);
[ 1, 2, 4, 5, 7, 8, 10, 11, 13, 14, 16, 17, 19, 20, 22, 23, 25, 26, 27, 27, 
  27, 27, 27, 27, 27, 27, 27, 26, 25, 23, 22, 20, 19, 17, 16, 14, 13, 11, 10, 
  8, 7, 5, 4, 2, 1 ]

This function computes an ascending chain of subgroups from U to G. This chain is given as a list whose first entry is U and the last entry is G. The function tries to make the links in this chain small.

The option refineIndex can be used to give a bound for refinements of steps to avoid GAP trying to enforce too small steps.

This routine tries to find a subgroup E of G, such that G > E > U. If U is maximal, it returns false. This is done by finding minimal blocks for the operation of G on the right cosets of U.

returns a list of all subgroups of G that properly contain U; that is all subgroups between G and U. It returns a record with components subgroups which is a list of these subgroups as well as a component inclusions which lists all maximality inclusions among these subgroups. A maximality inclusion is given as a list [i,j] indicating that subgroup number i is a maximal subgroup of subgroup number j, the numbers 0 and 1+length(subgroups) are used to denote U and G respectively.

37.17 Factor Groups

returns a homomorphism from G to another group whose kernel is N. GAP will try to select the image group as to make computations in it as efficient as possible. As the factor group G /N can be identified with the image of G this permits efficient computations in the factor group. The homomorphism returned is not necessarily surjective, so ImagesSource should be used instead of Range to get a group isomorphic to the factor group. The NC variant does not check whether N is normal in G.

returns the image of the NaturalHomomorphismByNormalSubgroup(G,N). The NC version does not test whether N is normal in G.

gap> g:=Group((1,2,3,4),(1,2));;n:=Subgroup(g,[(1,2)(3,4),(1,3)(2,4)]);;
gap> hom:=NaturalHomomorphismByNormalSubgroup(g,n);
[ (1,2,3,4), (1,2) ] -> [ f1*f2, f1 ]
gap> Size(ImagesSource(hom));
6
gap> FactorGroup(g,n);
Group([ f1, f2 ])

computes the commutator factor group G /G ^¢ of the group G.

gap> CommutatorFactorGroup(g);
Group([ f1 ])

returns an epimorphism from grp onto the maximal abelian quotient of grp. the kernel of this epimorphism is the derived subgroup.

tests whether G/N is abelian (without explicitly constructing the factor group).

tests whether G/N is elementary abelian (without explicitly constructing the factor group).

gap> HasAbelianFactorGroup(g,n);
false
gap> HasAbelianFactorGroup(DerivedSubgroup(g),n);
true

Computes the full preimage of the centralizer C_G/N(elm·N) in G (without necessarily constructing the factor group).

gap> CentralizerModulo(g,n,(1,2));
Group([ (3,4), (1,3)(2,4), (1,4)(2,3) ])

37.18 Sets of Subgroups

generates the conjugacy class of subgroups of G with representative U. This class is an external set, so functions such as Representative, (which returns U), ActingDomain (which returns G), StabilizerOfExternalSet (which returns the normalizer of U), and AsList work for it.

(The use the [] list access to select elements of the class is considered obsolescent and will be removed in future versions. Use ClassElementLattice instead.)

gap> g:=Group((1,2,3,4),(1,2));;IsNaturalSymmetricGroup(g);;
gap> cl:=ConjugacyClassSubgroups(g,Subgroup(g,[(1,2)]));
Group( [ (1,2) ] )^G
gap> Size(cl);
6
gap> ClassElementLattice(cl,4);
Group([ (2,3) ])

Is the representation GAP uses for conjugacy classes of subgroups. It can be used to check whether an object is a class of subgroups. The second representation IsConjugacyClassSubgroupsByStabilizerRep in addition is an external orbit by stabilizer and will compute its elements via a transversal of the stabilizer.

This attribute returns a list of all conjugacy classes of subgroups of the group G. It also is applicable for lattices of subgroups (see LatticeSubgroups). The order in which the classes are listed depends on the method chosen by GAP. For each class of subgroups, a representative can be accessed using Representative (see Representative).

gap> ConjugacyClassesSubgroups(g);
[ Group( () )^G, Group( [ (1,3)(2,4) ] )^G, Group( [ (1,2) ] )^G, 
  Group( [ (2,4,3) ] )^G, Group( [ (1,4)(2,3), (1,3)(2,4) ] )^G, 
  Group( [ (1,2)(3,4), (1,2) ] )^G, Group( [ (1,2)(3,4), (1,4,2,3) ] )^G, 
  Group( [ (3,4), (2,4,3) ] )^G, Group( [ (1,3)(2,4), (1,4)(2,3), (1,2) ] )^G,
  Group( [ (1,3)(2,4), (1,4)(2,3), (2,4,3) ] )^G, 
  Group( [ (1,3)(2,4), (1,4)(2,3), (2,4,3), (1,2) ] )^G ]

returns the conjugacy classes of maximal subgroups of G. Representatives of the classes can be computed directly by MaximalSubgroupClassReps (see MaximalSubgroupClassReps).

gap> ConjugacyClassesMaximalSubgroups(g);
[ AlternatingGroup( [ 1 .. 4 ] )^G, Group( [ (1,2,3), (1,2) ] )^G, 
  Group( [ (1,2), (3,4), (1,3)(2,4) ] )^G ]

returns a list of conjugacy representatives of the maximal subgroups of G.

gap> MaximalSubgroupClassReps(g);
[ Alt( [ 1 .. 4 ] ), Group([ (1,2,3), (1,2) ]), 
  Group([ (1,2), (3,4), (1,3)(2,4) ]) ]

returns a list of all maximal subgroups of G. This may take up much space, therefore the command should be avoided if possible. See ConjugacyClassesMaximalSubgroups.

gap> MaximalSubgroups(Group((1,2,3),(1,2)));
[ Group([ (1,2,3) ]), Group([ (2,3) ]), Group([ (1,2) ]), Group([ (1,3) ]) ]

returns a list of all normal subgroups of G.

gap> g:=SymmetricGroup(4);;NormalSubgroups(g);
[ Group(()), Group([ (1,4)(2,3), (1,3)(2,4) ]), 
  Group([ (2,4,3), (1,4)(2,3), (1,3)(2,4) ]), Sym( [ 1 .. 4 ] ) ]

is a list containing those proper normal subgroups of the group G that are maximal among the proper normal subgroups.

gap> MaximalNormalSubgroups( g );
[ Group([ (2,4,3), (1,4)(2,3), (1,3)(2,4) ]) ]

37.19 Subgroup Lattice

The GAP package XGAP permits a graphical display of the lattice of subgroups in a nice way.

computes the lattice of subgroups of the group G. This lattice has the conjugacy classes of subgroups as attribute ConjugacyClassesSubgroups (see ConjugacyClassesSubgroups) and permits one to test maximality/minimality relations.

gap> g:=SymmetricGroup(4);;
gap> l:=LatticeSubgroups(g);
<subgroup lattice of Sym( [ 1 .. 4 ] ), 11 classes, 30 subgroups>
gap> ConjugacyClassesSubgroups(l);
[ Group( () )^G, Group( [ (1,3)(2,4) ] )^G, Group( [ (1,2) ] )^G, 
  Group( [ (2,4,3) ] )^G, Group( [ (1,4)(2,3), (1,3)(2,4) ] )^G, 
  Group( [ (1,2)(3,4), (1,2) ] )^G, Group( [ (1,2)(3,4), (1,4,2,3) ] )^G, 
  Group( [ (3,4), (2,4,3) ] )^G, Group( [ (1,3)(2,4), (1,4)(2,3), (1,2) ] )^G,
  Group( [ (1,3)(2,4), (1,4)(2,3), (2,4,3) ] )^G, 
  Group( [ (1,3)(2,4), (1,4)(2,3), (2,4,3), (1,2) ] )^G ]

For a class C of subgroups, obtained by a lattice computation, this operation returns the n-th conjugate subgroup in the class.

Because of other methods installed, AsList(C) can give a different arrangement of the class elements!

For a lattice lat of subgroups this attribute contains the maximal subgroup relations among the subgroups of the lattice. It is a list, corresponding to the ConjugacyClassesSubgroups of the lattice, each entry giving a list of the maximal subgroups of the representative of this class. Every maximal subgroup is indicated by a list of the form [cls,nr] which means that the nrst subgroup in class number cls is a maximal subgroup of the representative.

The number nr corresponds to access via ClassElementLattice and not necessarily the AsList arrangement! See also MinimalSupergroupsLattice.

gap> MaximalSubgroupsLattice(l);
[ [  ], [ [ 1, 1 ] ], [ [ 1, 1 ] ], [ [ 1, 1 ] ], 
  [ [ 2, 1 ], [ 2, 2 ], [ 2, 3 ] ], [ [ 3, 1 ], [ 3, 6 ], [ 2, 3 ] ], 
  [ [ 2, 3 ] ], [ [ 4, 1 ], [ 3, 4 ], [ 3, 5 ], [ 3, 6 ] ], 
  [ [ 7, 1 ], [ 6, 1 ], [ 5, 1 ] ], 
  [ [ 5, 1 ], [ 4, 1 ], [ 4, 2 ], [ 4, 3 ], [ 4, 4 ] ], 
  [ [ 10, 1 ], [ 9, 1 ], [ 9, 2 ], [ 9, 3 ], [ 8, 1 ], [ 8, 2 ], [ 8, 3 ], 
      [ 8, 4 ] ] ]
gap> last[6];
[ [ 3, 1 ], [ 3, 6 ], [ 2, 3 ] ]
gap> u1:=Representative(ConjugacyClassesSubgroups(l)[6]);
Group([ (1,2)(3,4), (1,2) ])
gap> u2:=ClassElementLattice(ConjugacyClassesSubgroups(l)[3],1);;
gap> u3:=ClassElementLattice(ConjugacyClassesSubgroups(l)[3],6);;
gap> u4:=ClassElementLattice(ConjugacyClassesSubgroups(l)[2],3);;
gap> IsSubgroup(u1,u2);IsSubgroup(u1,u3);IsSubgroup(u1,u4);
true
true
true

For a lattice lat of subgroups this attribute contains the minimal supergroup relations among the subgroups of the lattice. It is a list, corresponding to the ConjugacyClassesSubgroups of the lattice, each entry giving a list of the minimal supergroups of the representative of this class. Every minimal supergroup is indicated by a list of the form [cls,nr] which means that the nrst subgroup in class number cls is a minimal supergroup of the representative.

The number nr corresponds to access via ClassElementLattice and not necessarily the AsList arrangement! See also MaximalSubgroupsLattice.

gap> MinimalSupergroupsLattice(l);
[ [ [ 2, 1 ], [ 2, 2 ], [ 2, 3 ], [ 3, 1 ], [ 3, 2 ], [ 3, 3 ], [ 3, 4 ], 
      [ 3, 5 ], [ 3, 6 ], [ 4, 1 ], [ 4, 2 ], [ 4, 3 ], [ 4, 4 ] ], 
  [ [ 5, 1 ], [ 6, 2 ], [ 7, 2 ] ], [ [ 6, 1 ], [ 8, 2 ], [ 8, 3 ] ], 
  [ [ 8, 1 ], [ 10, 1 ] ], [ [ 9, 1 ], [ 9, 2 ], [ 9, 3 ], [ 10, 1 ] ], 
  [ [ 9, 1 ] ], [ [ 9, 1 ] ], [ [ 11, 1 ] ], [ [ 11, 1 ] ], [ [ 11, 1 ] ], 
  [  ] ]
gap> last[3];
[ [ 6, 1 ], [ 8, 2 ], [ 8, 3 ] ]
gap> u5:=ClassElementLattice(ConjugacyClassesSubgroups(l)[8],2);
Group([ (1,2), (1,4,2) ])
gap> u6:=ClassElementLattice(ConjugacyClassesSubgroups(l)[8],3);
Group([ (1,2), (1,2,3) ])
gap> IsSubgroup(u5,u2);
true
gap> IsSubgroup(u6,u2);
true

returns a list of conjugacy representatives of perfect (respectively simple) subgroups of G. This uses the library of perfect groups (see PerfectGroup), thus it will issue an error if the library is insufficient to determine all perfect subgroups.

gap> m11:=TransitiveGroup(11,6);
M(11)
gap> r:=RepresentativesPerfectSubgroups(m11);
[ Group([ (1,6,8)(3,5,11)(7,9,10), (1,7)(4,9)(5,10)(8,11) ]), 
  Group([ (1,5,7)(2,9,11)(3,10,6), (1,7)(4,9)(5,10)(8,11) ]), 
  Group([ (1,11)(3,8)(5,6)(9,10), (1,10,7,5)(4,11,9,8) ]), 
  Group([ (1,10,11)(2,7,6)(3,8,9), (1,7)(4,9)(5,10)(8,11) ]), M(11), 
  Group(()) ]
gap> List(r,Size);
[ 60, 60, 360, 660, 7920, 1 ]

returns a list of the conjugacy classes of perfect subgroups of G. (see RepresentativesPerfectSubgroups.)

gap> ConjugacyClassesPerfectSubgroups(m11);
[ Group( [ ( 1, 6, 8)( 3, 5,11)( 7, 9,10), ( 1, 7)( 4, 9)( 5,10)( 8,11) ] )^G,
  Group( [ ( 1, 5, 7)( 2, 9,11)( 3,10, 6), ( 1, 7)( 4, 9)( 5,10)( 8,11) ] )^G,
  Group( [ ( 1,11)( 3, 8)( 5, 6)( 9,10), ( 1,10, 7, 5)( 4,11, 9, 8) ] )^G, 
  Group( [ ( 1,10,11)( 2, 7, 6)( 3, 8, 9), ( 1, 7)( 4, 9)( 5,10)( 8,11) ] )^G,
  M(11)^G, Group( () )^G ]

The Zuppos of a group are the cyclic subgroups of prime power order. (The name ``Zuppo'' derives from the German abbreviation for ``zyklische Untergruppen von Primzahlpotenzordnung''.) This attribute gives generators of all such subgroups of a group G. That is all elements of G of prime power order up to the equivalence that they generate the same cyclic subgroup.

is the information class used by the cyclic extension methods for subgroup lattice calculations.

37.20 Specific Methods for Subgroup Lattice Computations

computes the lattice of G using the cyclic extension algorithm. If the function func is given, the algorithm will discard all subgroups not fulfilling func (and will also not extend them), returning a partial lattice. This can be useful to compute only subgroups with certain properties. Note however that this will not necessarily yield all subgroups that fulfill func, but the subgroups whose subgroups are used for the construction must also fulfill func as well. (In fact the filter func will simply discard subgroups in the cyclic extension algorithm. Therefore the trivial subgroup will always be included.) Also note, that for such a partial lattice maximality/minimality inclusion relations cannot be computed.

The cyclic extension algorithm requires the perfect subgroups of G. However GAP cannot analyze the function func for its implication but can only apply it. If it is known that func implies solvability, the computation of the perfect subgroups can be avoided by giving a third parameter noperf set to true.

gap> g:=WreathProduct(Group((1,2,3),(1,2)),Group((1,2,3,4)));;
gap> l:=LatticeByCyclicExtension(g,function(G)
> return Size(G) in [1,2,3,6];end);
<subgroup lattice of <permutation group of size 5184 with 9 generators>, 
47 classes, 2628 subgroups, restricted under further condition l!.func>

The total number of classes in this example is much bigger, as the following example shows:

gap> LatticeSubgroups(g);
<subgroup lattice of <permutation group of size 5184 with 9 generators>, 
566 classes, 27134 subgroups>

Let G be an elementary abelian group (that is a vector space) and homs a set of automorphisms of G. Then this function computes all subspaces of G which are invariant under all automorphisms in homs. When considering G as a module for the algebra generated by homs, these are all submodules. If homs is empty, it computes all subspaces. If the optional parameter dims is given, only subspaces of this dimension are computed.

gap> g:=Group((1,2,3),(4,5,6),(7,8,9));
Group([ (1,2,3), (4,5,6), (7,8,9) ])
gap> hom:=GroupHomomorphismByImages(g,g,[(1,2,3),(4,5,6),(7,8,9)],
> [(7,8,9),(1,2,3),(4,5,6)]);
[ (1,2,3), (4,5,6), (7,8,9) ] -> [ (7,8,9), (1,2,3), (4,5,6) ]
gap> u:=InvariantSubgroupsElementaryAbelianGroup(g,[hom]);
[ Group(()), Group([ (1,2,3)(4,5,6)(7,8,9) ]), 
  Group([ (1,3,2)(7,8,9), (1,3,2)(4,5,6) ]), 
  Group([ (7,8,9), (4,5,6), (1,2,3) ]) ]

This function (implementing the algorithm published in Hulpke99) computes subgroups of a solvable group G, using the homomorphism principle. It returns a list of representatives up to G-conjugacy.

The optional argument opt is a record, which may be used to put restrictions on the subgroups computed. The following record components of opt are recognized and have the following effects:

actions

must be a list of automorphisms of G. If given, only groups which are invariant under all these automorphisms are computed. The algorithm must know the normalizer in G of the group generated by actions (defined formally by embedding in the semidirect product of G with actions). This can be given in the component funcnorm and will be computed if this component is not given.

normal

if set to true only normal subgroups are guaranteed to be returned (though some of the returned subgroups might still be not normal).

consider

a function to restrict the groups computed. This must be a function of five parameters, C,A,N,B,M, that are interpreted as follows: The arguments are subgroups of a factor F of G in the relation F ³ C > A > N > B > M. N and M are normal subgroups. C is the full preimage of the normalizer of A/N in F/N. When computing modulo M and looking for subgroups U such that UÇN=B and áU,Nñ = A, this function is called. If it returns false all potential groups U (and therefore all groups later arising from them) are disregarded. This can be used for example to compute only subgroups of certain sizes.

(This is just a restriction to speed up computations. The function may still return (invariant) subgroups which don't fulfill this condition!) This parameter is used to permit calculations of some subgroups if the set of all subgroups would be too large to handle.

The actual groups C, A, N and B which are passed to this function are not necessarily subgroups of G but might be subgroups of a proper factor group F=G/H. Therefore the consider function may not relate the parameter groups to G.

retnorm

if set to true the function not only returns a list subs of subgroups but also a corresponding list norms of normalizers in the form [subs,norms].

series

is an elementary abelian series of G which will be used for the computation.

groups

is a list of groups to seed the calculation. Only subgroups of these groups are constructed.

gap> g:=Group((1,2,3),(1,2),(4,5,6),(4,5),(7,8,9),(7,8));
Group([ (1,2,3), (1,2), (4,5,6), (4,5), (7,8,9), (7,8) ])
gap> hom:=GroupHomomorphismByImages(g,g,
> [(1,2,3),(1,2),(4,5,6),(4,5),(7,8,9),(7,8)],
> [(4,5,6),(4,5),(7,8,9),(7,8),(1,2,3),(1,2)]);
[ (1,2,3), (1,2), (4,5,6), (4,5), (7,8,9), (7,8) ] -> 
[ (4,5,6), (4,5), (7,8,9), (7,8), (1,2,3), (1,2) ]
gap> l:=SubgroupsSolvableGroup(g,rec(actions:=[hom]));;
gap> List(l,Size);
[ 1, 3, 9, 27, 54, 2, 6, 18, 108, 4, 216, 8 ]
gap> Length(ConjugacyClassesSubgroups(g)); # to compare
162

This function returns a function consider of four arguments that can be used in SubgroupsSolvableGroup (see SubgroupsSolvableGroup) for the option consider to compute subgroups whose sizes are divisible by size.

gap> l:=SubgroupsSolvableGroup(g,rec(actions:=[hom],
> consider:=SizeConsiderFunction(6)));;
gap> List(l,Size);
[ 1, 3, 9, 27, 54, 6, 18, 108, 216 ]

This function returns a function consider of four arguments that can be used in SubgroupsSolvableGroup (see SubgroupsSolvableGroup) for the option consider to compute subgroups whose sizes are exactly size.

gap> l:=SubgroupsSolvableGroup(g,rec(actions:=[hom],
> consider:=ExactSizeConsiderFunction(6)));;
gap> List(l,Size);
[ 1, 3, 9, 27, 54, 6, 108, 216 ]

Information function for the subgroup lattice functions using pcgs.

37.21 Special Generating Sets

returns a ``smallest'' generating set for the group G. This is the lexicographically (using GAPs order of group elements) smallest list l of elements of G such that G=álñ and l_i Ï ál₁,¼,l_i-1ñ (in particular l₁ is not the one of the group). The comparison of two groups via lexicographic comparison of their sorted element lists yields the same relation as lexicographic comparison of their smallest generating sets.

gap> g:=SymmetricGroup(4);;
gap> GeneratorsSmallest(g);
[ (3,4), (2,3), (1,2) ]

returns the largest element of G with respect to the ordering < of the elements family.

returns a generating set of G of minimal possible length.

gap> MinimalGeneratingSet(g);
[ (2,4,3), (1,4,2,3) ]

returns a generating set of G which has few elements. As neither irredundancy, nor minimal length is proven it runs much faster than MinimalGeneratingSet. It can be used whenever a short generating set is desired which not necessarily needs to be optimal.

gap> SmallGeneratingSet(g);
[ (1,2), (1,2,3,4) ]

returns a set of generators g of prime-power order of the abelian group A such that A is the direct product of the cyclic groups generated by the g_i.

gap> g:=AbelianGroup(IsPermGroup,[15,14,22,78]);;
gap> List(IndependentGeneratorsOfAbelianGroup(g),Order);
[ 2, 2, 2, 3, 3, 5, 7, 11, 13 ]

37.22 1-Cohomology

Let G be a finite group and M an elementary abelian normal p-subgroup of G. Then the group of 1-cocycles Z¹( G/M, M ) is defined as

Z1(G/M, M) = { g: G/M ® M | "g1, g2 Î G : g(g1 M ·g2 M ) = g(g1 M)g2 ·g(g2 M) }

and is a GF(p)-vector space.

The group of 1-coboundaries B¹( G/M, M ) is defined as

B1(G/M, M) = { g: G/M ® M | $m Î M "g Î G : g(gM) = (m-1)g ·m }

It also is a GF(p)-vector space.

Let a be the isomorphism of M into a row vector space W and (g₁,¼,g_l) representatives for a generating set of G/M. Then there exists a monomorphism b of Z¹( G/M, M ) in the l-fold direct sum of W, such that b( g) = ( a( g(g₁ M) ),¼, a( g(g_l M) ) ) for every g Î Z¹( G/M, M ).

Computes the group of 1-Cocycles Z¹(G /M ,M ). The normal subgroup M may be given by a (Modulo)Pcgs mpcgs. In this case the whole calculation is performed modulo the normal subgroup defined by the DenominatorOfModuloPcgs(mpcgs) (see Polycyclic Generating Systems). Similarly the group G may instead be specified by a set of elements gens that are representatives for a generating system for the factor group G/M. If this is done the 1-Cocycles are computed with respect to these generators (otherwise the routines try to select suitable generators themselves).

computes the group of 1-coboundaries. Syntax of input and output otherwise is the same as with OneCocycles except that entries that refer to cocycles are not computed.

The operations OneCocycles and OneCoboundaries return a record with (at least) the components:

generators

Is a list of representatives for a generating set of G/M. Cocycles are represented with respect to these generators.

oneCocycles

A space of row vectors over GF(p), representing Z¹. The vectors are represented in dimension a·b where a is the length of generators and p^b the size of M.

oneCoboundaries

A space of row vectors that represents B¹.

cocycleToList

is a function to convert a cocycle (a row vector in oneCocycles) to a corresponding list of elements of M.

listToCocycle

is a function to convert a list of elements of M to a cocycle.

isSplitExtension

indicates whether G splits over M. The following components are only bound if the extension splits. Note that if M is given by a modulo pcgs all subgroups are given as subgroups of G by generators corresponding to generators and thus may not contain the denominator of the modulo pcgs. In this case taking the closure with this denominator will give the full preimage of the complement in the factor group.

complement

One complement to M in G.

cocycleToComplement(cyc)

is a function that takes a cocycle from oneCocycles and returns the corresponding complement to M in G (with respect to the fixed complement complement).

complementToCocycle(U)

is a function that takes a complement and returns the corresponding cocycle.

If the factor G/M is given by a (modulo) pcgs gens then special methods are used that compute a presentation for the factor implicitly from the pcgs.

Note that the groups of 1-cocycles and 1-coboundaries are not Groups in the sense of GAP but vector spaces.

gap> g:=Group((1,2,3,4),(1,2));;
gap> n:=Group((1,2)(3,4),(1,3)(2,4));;
gap> oc:=OneCocycles(g,n);
rec( oneCoboundaries := <vector space over GF(2), with 2 generators>, 
  oneCocycles := <vector space over GF(2), with 2 generators>, 
  generators := [ (3,4), (2,4,3) ], isSplitExtension := true, 
  complement := Group([ (3,4), (2,4,3) ]), 
  cocycleToList := function( c ) ... end, 
  listToCocycle := function( L ) ... end, 
  cocycleToComplement := function( c ) ... end, 
  factorGens := [ (3,4), (2,4,3) ], 
  complementToCocycle := function( K ) ... end )
gap> oc.cocycleToList([ 0*Z(2), Z(2)^0, 0*Z(2), Z(2)^0 ]);
[ (1,2)(3,4), (1,2)(3,4) ]
gap> oc.listToCocycle([(),(1,3)(2,4)]);
[ 0*Z(2), 0*Z(2), Z(2)^0, 0*Z(2) ]
gap> oc.cocycleToComplement([ 0*Z(2), Z(2)^0, 0*Z(2), Z(2)^0 ]);
Group([ (1,2), (1,2,3) ])
gap> oc.cocycleToComplement([ 0*Z(2), 0*Z(2), Z(2)^0, 0*Z(2) ]);
Group([ (3,4), (1,3,4) ])
gap> oc.complementToCocycle(Group((1,2,4),(1,4)));
[ 0*Z(2), Z(2)^0, Z(2)^0, Z(2)^0 ]

The factor group H¹(G/M,M)=Z¹(G/M,M)/B¹(G/M,M) is called the first cohomology group. Currently there is no function which explicitly computes this group. The easiest way to represent it is as a vector space complement to B¹ in Z¹.

If the only purpose of the calculation of H¹ is the determination of complements it might be desirable to stop calculations once it is known that the extension cannot split. This can be achieved via the more technical function OCOneCocycles.

is the more technical function to compute 1-cocycles. It takes an record ocr as first argument which must contain at least the components group for G and modulePcgs for a (modulo) pcgs of M. This record will also be returned with components as described under OneCocycles (with the exception of isSplitExtension which is indicated by the existence of a complement) but components such as oneCoboundaries will only be computed if not already present.

If onlySplit is true, OneCocyclesOC returns false as soon as possible if the extension does not split.

computes Complementclasses to an elementary abelian normal subgroup N via 1-Cohomology. Normally, a user program should call Complementclasses (see Complementclasses) instead, which also works for a solvable (not necessarily elementary abelian) N.

The info class for the cohomology calculations is InfoCoh.

37.23 Schur Covers and Multipliers

returns an epimorphism epi from a group D onto G. The group D is one (of possibly several) Schur covers of G. The group D can be obtained as the Source of epi. the kernel of epi is the schur multiplier of G. If pl is given as a list of primes, only the multiplier part for these primes is realized. At the moment, D is represented as a finitely presented group.

returns one (of possibly several) Schur covers of G.

At the moment this cover is represented as a finitely presented group and IsomorphismPermGroup would be needed to convert it to a permutation group.

If also the relation to G is needed, EpimorphismSchurCover should be used.

gap> g:=Group((1,2,3,4),(1,2));;
gap> epi:=EpimorphismSchurCover(g);
[ f1, f2, f3 ] -> [ (3,4), (2,4,3), (1,4)(2,3) ]
gap> Size(Source(epi));
48

If the group becomes bigger, Schur Cover calculations might become unfeasible.

There is another operation which only returns the structure of the Multiplier, and which should work for larger groups as well.

returns a list of the abelian invariants of the Schur multiplier of G.

gap> AbelianInvariantsMultiplier(g);
[ 2 ]
gap> AbelianInvariantsMultiplier(MathieuGroup(22));
[ 4, 3 ]

Note that the following example will take some time.

gap> AbelianInvariantsMultiplier(PSU(6,2));
[ 2, 2, 3 ]

At the moment, this operation will not give any information about how to extend the multiplier to a Schur Cover.

37.24 Tests for the Availability of Methods

The following filters and operations indicate capabilities of GAP. They can be used in the method selection or algorithms to check whether it is feasible to compute certain operations for a given group. In general, they return true if good algorithms for the given arguments are available in GAP. An answer false indicates that no method for this group may exist, or that the existing methods might run into problems.

Typical examples when this might happen is with finitely presented groups, for which many of the methods cannot be guaranteed to succeed in all situations.

The willingness of GAP to perform certain operations may change, depending on which further information is known about the arguments. Therefore the filters used are not implemented as properties but as ``other filters'' (see Properties and Other Filters).

This filter indicates whether a group can test membership of elements in grp (via the operation in) in reasonable time. It is used by the method selection to decide whether an algorithm that relies on membership tests may be used.

This filter indicates whether the size of the domain dom (which might be infinity) can be computed.

This filter indicates whether grp can easily compute the size of any subgroup. (This is for example advantageous if one can test that a stabilizer index equals the length of the orbit computed so far to stop early.)

This filter indicates whether the index [G:H] (which might be infinity) can be computed. It assumes that H £ G. (see CanComputeIsSubset)

This filter indicates that GAP can test (via IsSubset) whether B is a subset of A.

Tests whether the group G can decompose elements in the generators gens. If gens is not given it tests, whether it can decompose in the generators given in GeneratorsOfGroup.

This property can be used for example to check whether a GroupHomomorphismByImages can be reasonably defined from this group.

[Top] [Up] [Previous] [Next] [Index]

GAP 4 manual
May 2002